class DarkKnightMut extends Mutator
Config;

var array<xPlayer> NewPlayers;
var config array<string> PlayerIDs;

function PreBeginPlay()
{
AddToPackageMap("DarkKnight");
AddToPackageMap("DarkKnightMod");
Class'KFGameType'.Default.AvailableChars[Class'KFGameType'.Default.AvailableChars.Length] = "DarkKnight";
}

function bool CheckReplacement(Actor Other, out byte bSuperRelevant)
{
if( xPlayer(Other)!=None)
{
NewPlayers[NewPlayers.Length] = xPlayer(Other);
SetTimer(0.1,false);
}
return true;
}

function Timer()
{
while( NewPlayers.Length>0 )
{
if( NewPlayers[0]!=None && NewPlayers[0].Player!=None && ShouldSkin(NewPlayers[0].GetPlayerIDHash()) )
NewPlayers[0].SetPawnClass("","DarkKnight");
NewPlayers.Remove(0,1);
}
}

final function bool ShouldSkin( string ID )
{
local int i;

for( i=(PlayerIDs.Length-1); i>=0; --i )
if( PlayerIDs[i]==ID )
return true;
return false;
}

defaultproperties
{
bAddToServerPackages=true
GroupName="KF_DarkKnight"
FriendlyName="DarkKnight character"
Description="Skin Dark Knight"
bAlwaysRelevant=true
}

class DarkKnight extends PlayerRecordClass;

#exec OBJ LOAD FILE=DarkKnight.ukx

simulated static function xUtil.PlayerRecord FillPlayerRecord()
{
local xUtil.PlayerRecord PRE;

PRE.Species = Class'DarkKnightMod.DarkKnightSpecies';
PRE.MeshName = "DarkKnight.sawDKnightMesh";
PRE.BodySkinName = "DarkKnight.Body_KS_cmb";
PRE.FaceSkinName = "DarkKnight.Cape_cmb";
PRE.Portrait = Texture'PotKnight';
PRE.TextName = "DarkKnight Knight Skin";
PRE.VoiceClassName = "KFMod.KFVoicePack";
PRE.Sex = "M";
PRE.Menu = "SP";
PRE.Skeleton = "KFSoldiers.Soldier";
PRE.Ragdoll = "British_Soldier1";
return PRE;
}

class DarkKnightSpecies extends CivilianSpeciesThree;

#exec OBJ LOAD FILE=DarkKnight.ukx
static function bool Setup(Pawn P, xUtil.PlayerRecord rec)
{
P.Skins.Length = 1;
P.Skins[0] = Combiner'DarkKnight.Body_KS_cmb';
return Super.Setup(P,rec);
}

defaultproperties
{
DetachedArmClass=None
DetachedLegClass=None
SleeveTexture=Combiner'DarkKnight.BatHands1stP_cmb'
}